;INADEQUATE PULSE SEQUENCE FOR DOUBLE-QUANTUM EXCITATION IN STRONGLY-COUPLED 2-SPIN-1/2 SYSTEMS
;FROM "Spinor Double-Quantum Excitation in the Solution NMR of Near-Equivalent Spin-1/2 Pairs"
;for assistance, contact mohamed@sabba.me

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"d11=30m"

"acqt0=-p1*2/3.1416"

define delay tauINAD
"tauINAD = d2-p1*10"

"cnst21=90+asin(1/8)*DEG"
"cnst22=3*cnst21"
"cnst23=90+asin(1/4)*DEG"
"cnst24=3*cnst23"

"l2 = 0.5*l1"

1 ze
2 d1  pl1:f1 


;BLOCK A: Iz to DQCs

	;STEP 1: 90(y) pulse to create transverse magnetization

		3 (p1*0.5 ph1):f1                 
      (p1*2 ph1+cnst21):f1                
      (p1*4 ph1+cnst22):f1                 ; BB1 90(+y) pulse
      (p1*2 ph1+cnst21):f1                
      (p1*0.5 ph1):f1               

	;STEP 3: spin echo

		4 tauINAD*0.5
      (p1 ph2):f1                 
      (p1*2 ph2+cnst23):f1           
      (p1*4 ph2+cnst24):f1          ; BB1 180(x) pulse
      (p1*2 ph2+cnst23):f1             
      (p1 ph2):f1        
      tauINAD*0.5

	;STEP 4: 90(y) pulse to create DQCs

    5 (p1*0.5 ph1):f1                 
      (p1*2 ph1+cnst21):f1                
      (p1*4 ph1+cnst22):f1                 ; BB1 90(+y) pulse
      (p1*2 ph1+cnst21):f1                
      (p1*0.5 ph1):f1          

;BLOCK A: DQCs to Iz

	;STEP 5: 90(y) pulse to create transverse magnetization

	 6  (p1*0.5 ph11):f1                 
      (p1*2 ph11+cnst21):f1                
      (p1*4 ph11+cnst22):f1                 ; BB1 90(+y) pulse
      (p1*2 ph11+cnst21):f1                
      (p1*0.5 ph11):f1          

	;STEP 6: spin echo

		7 tauINAD*0.5
      (p1 ph12):f1                 
      (p1*2 ph12+cnst23):f1           
      (p1*4 ph12+cnst24):f1          ; BB1 180(x) pulse
      (p1*2 ph12+cnst23):f1             
      (p1 ph12):f1        
      tauINAD*0.5
 

	;STEP 8: 90(y) pulse to create Iz

    8 (p1*0.5 ph11):f1                 
      (p1*2 ph11+cnst21):f1                
      (p1*4 ph11+cnst22):f1                 ; BB1 90(+y) pulse
      (p1*2 ph11+cnst21):f1                
      (p1*0.5 ph11):f1      

;READOUT BLOCK
  ;STEP 9: z-filter
    40u UNBLKGRAD
    p21:gp1                        ; gradient pulse
    2m
    40u BLKGRAD

    9 (p1*0.5 ph20):f1                 
      (p1*2 ph20+cnst21):f1                
      (p1*4 ph20+cnst22):f1                 ; BB1 90(-x) pulse
      (p1*2 ph20+cnst21):f1                
      (p1*0.5 ph20):f1    

  go=2 ph31
  30m mc #0 to 2 F0(zd)
exit

;BLOCK A PHASES
  ;PULSE 1
	ph1= 1 1 1 1
  ;180 PULSE BASE PHASE
  ph2= 0 0 0 0
;BLOCK B PHASES
  ;PHI_{B}
  ph10=0 1 2 3
  ;PULSE 1
	ph11=ph1+ph10
  ;180 PULSE BASE PHASE
  ph12=ph2+ph10
  ;READOUT PULSE 
  ph20=2 3 0 1

;Receiver phases
ph31=0 3 2 1

;d2 : duration of the INADEQUATE spin echo; for strong coupling this is J/Delta^2
;p1 : high power 90 pulse duration
;plw1 : pulse power (hard pulses)
;p21 : gradient pulse duration