;SLIC PULSE SEQUENCE FOR DOUBLE-QUANTUM EXCITATION IN STRONGLY-COUPLED 2-SPIN-1/2 SYSTEMS
;FROM "Spinor Double-Quantum Excitation in the Solution NMR of Near-Equivalent Spin-1/2 Pairs"
;for assistance, contact mohamed@sabba.me

#include <Avance.incl>
#include <Grad.incl>

"p2=p1*2"
"d11=30m"
"p11=d2"

"acqt0=-p1*2/3.1416"

"cnst21=90+asin(1/8)*DEG"
"cnst22=3*cnst21"

1 ze
2 d1  pl1:f1 
3u pl11:f1

;BLOCK A: Iz to DQCs

	;STEP 1: 90(y) pulse to create transverse magnetization

   3 	(p11 ph3+cnst11):f1                ; SL(x)   
  	  3u pl1:f1                   ; return to hard pulse power
	;STEP 3: 90(x) pulse to create DQCs
    4  (p1*0.5 ph5):f1                 
       (p1*2 ph5+cnst21):f1                
       (p1*4 ph5+cnst22):f1                 ; BB1 90(+x) pulse
       (p1*2 ph5+cnst21):f1                
       (p1*0.5 ph5):f1    

;BLOCK A: DQCs to Iz

	;STEP 4: 90(y) pulse to create transverse magnetization

	;STEP 5: full SLIC sequence which generates an Ix12 Hamiltonian

	;STEP 6: 90(x) pulse to create Iz

    5  (p1*0.5 ph15):f1                 
       (p1*2 ph15+cnst21):f1                
       (p1*4 ph15+cnst22):f1                 ; BB1 90(+x) pulse
       (p1*2 ph15+cnst21):f1                
       (p1*0.5 ph15):f1    

		6 3u pl11:f1								  ; set SLIC power
 		  (p11 ph13+cnst11):f1                ; SL(x)   
  	  1u pl1:f1                   ; return to hard pulse power

;READOUT BLOCK
  ;STEP 7: z-filter
    40u UNBLKGRAD
    p21:gp1                        ; gradient pulse
    2m
    40u BLKGRAD
    7  (p1*0.5 ph20):f1                 
       (p1*2 ph20+cnst21):f1                
       (p1*4 ph20+cnst22):f1                 ; BB1 90(+x) pulse
       (p1*2 ph20+cnst21):f1                
       (p1*0.5 ph20):f1    

  go=2 ph31
  30m mc #0 to 2 F0(zd)
exit

;BLOCK A PHASES
  ;SLIC
	ph3= 0 0 0 0
  ;PULSE 2
	ph5= 0 0 0 0
;BLOCK B PHASES
  ;PHI_{B}
  ph10=0 1 2 3
  ;SLIC
	ph13=ph3+ph10
  ;PULSE 2
	ph15=ph5+ph10
;readout pulse
  ph20=2 3 0 1
;Receiver phases
ph31=0 3 2 1

;p11 : SLIC evolution duration: set to (round(sqrt(2)J/Delta))/J
;p1 : high power 90 pulse duration
;d1 : relaxation delay
;cnst11 : phase correction value (optional, in degrees)
;p21 : gradient pulse duration